Accident insurance | Vose Software

Accident insurance

See also: Insurance and finance risk analysis modeling introduction, Term life insurance

An insurance company will provide cover for financial loss associated with accidents for a fixed period, usually a year (for example: car, house, boat and fire insurance). The amount the insurer pays out is a function of the number of accidents that will occur and the cost to the insurer of each accident. The starting point is to assume that, for a given insured party, the accidents are unconnected to each other and occur randomly in time, which satisfies the assumptions underpinning a Poisson process. The frequency of accidents is then characterized by the expected frequency over the insured period.

Insurance companies nearly always apply a retention or deductible D. This means that the insured party pays the first part of the cost in an insured event up to D and the insurance company pays (cost-D) thereafter, so a cost x and claim size y are related as follows:

            y = MAX(x-D,0)

Most insurance policies also apply a maximum limit L so that if the cost of the risk event is greater than L+D the policy only pays out L. Then we have:

            y = IF(x-D<0,0,IF(x-D>L, L, x-D)) 

So, for example, if x = Lognormal(10,7), D = 5 and L = 25 we get the claim distribution  shown in the following figure:

Comparison of claim size with risk event cost distribution. Vertical lines with markers represent a probability mass.

Determining an aggregate distribution of claim sizes is simulation intensive, especially if the number of claims can be large but there are a couple of ways to speed up the simulation. Consider the following problem: historically we have observed 0.21 claims per insured party per year when the deductible was 8, and we wish to model the aggregate loss distribution for 3500 insured parties over a year with a new deductible of 5.

The claims data we had were truncated (this topic describes how to fit a distribution to truncated data). We'll assume that we were able to estimate the underlying risk event cost distribution to be the Lognormal(10,7) from above. Thus the expected rate of risk events was 1/(1-F(8)) times the rate of claims (where F(x) is the cumulative probability for a Lognormal(10,7)). The fraction of these events that will incur a claim is now (1-F(5)) so the new frequency of claims per insured party per year will be 0.21*(1-F(5))/(1-F(8)). From the figure above you can see that the claim size distribution excluding zero is a Lognormal distribution truncated at 5 and 30 and then shifted -5 units, i.e.:

 =VoseLognormal(10,7,,VoseXBounds(5,30),VoseShift(-5))

We can use this distribution to simulate only claims rather than the entire risk event cost. ModelRisk has a range of special functions that convert a distribution object into another object of the form of the figure above. For example, using VoseDeduct:

=VoseDeductObject(CostDistributionObject, deductible, maxlimit, zeros)

The zero parameter is either TRUE or FALSE (or omitted). If FALSE, the DeductObject has no probability mass at zero, i.e. it is the distribution of a claim size given that a claim has occurred. If TRUE, the DeductObject has probability mass at zero, i.e. it is the distribution of a claim size given that a risk event has occurred. The DeductObject can be used in all the usual ways, e.g. if we start with the Lognormal(10,7) distribution from above and apply a deductible and limit:

A1:      =VoseLognormalObject(10,7)

A2:      =VoseDeductObject(A1, 5, 25, TRUE)

The object in cell A2 can then be used in recursive and FFT aggregate methods, since these methods discretize the individual loss distribution and can therefore take care of a discrete-continuous mixture. Thus, we can use, for example:

=VoseAggregateFFT(VosePoissonObject(2700),A2) to simulate the cost of Poisson(2700) random claims

=VoseAggregateFFT(VosePoissonObject(2700),A2,0.99) to calculate the 99th percentile of the aggregate cost of Poisson(2700) random claims.

Non-standard insurance policies

See also: VoseExpression

Insurance policies are becoming ever more flexible in their terms, and more complex to model as a result. For example, we might have a policy with a deductible of 5, and a limit of 20 beyond which the insurer pays only half the damages. Using a cost distribution of Lognormal(31,23) and an accident frequency distribution of Delaporte(3,5,40) we can model this as follows:

A1: =VoseLognormalObject(31,23)

A2: =VoseExpression("IF(#1>20,(#1-25)/2,IF(#1<5,0,#1))",A1)

A3 (output): =VoseAggregateMC(VoseDelaporte(3,5,40),A2)

The VoseExpression function allows one a great deal of flexibility. The '#1' refers to the distribution linked to Cell A1. Each time the VoseExpression function is called it will generate a new value from the Lognormal distribution and perform the calculation replacing '#1' with the generated value. The Delaporte function will generate a value (call it n) from this distribution, and the AggregateMC function will then call the VoseExpression function n times, adding as it goes along and returning the sum into the spreadsheet.

The VoseExpression allows several random variables to take part in the calculation. For example:

=VoseExpression("#1*#2",VoseBernoulliObject(0.3),VoseLognormalObject(20,7))

will model a cost that follows a Lognormal(20,7) distribution with 30% probability and zero with 70% probability;

=VoseExpression("#1*(#2+#3)",VoseBernoulliObject(0.3),VoseLognormalObject(20,7),VoseParetoObject(4,7))

will model a cost that follows a (Lognormal(20,7)+ VosePareto(4,7)) distribution with 30% probability and zero with 70% probability.

Read on: Modeling a correlated insurance portfolio

 

ModelRisk

Monte Carlo simulation in Excel. Learn more

Spreadsheet risk analysis modeling

Tamara

Adding risk and uncertainty to your project schedule. Learn more

Project risk analysis

Navigation

Enterprise Risk Management software (ERM)

Learn more about our enterprise risk analysis management software tool, Pelican

Enterprise risk management software introduction

FREE MONTE CARLO SIMULATION SOFTWARE

For Microsoft Excel

Download your free copy of ModelRisk Basic today. Professional quality risk modeling software and no catches

Download ModelRisk Basic now

FREE PROJECT RISK SOFTWARE

For Primavera & Microsoft Project

Download your free copy of Tamara Basic today. Professional quality project risk software and no catches.

Download Tamara Basic now